No HID interrupt IN transfers

No, __swi isn't only available with RTX. The main difference is that RTX reserves a couple of numbers. If I remember correct, __swi(0) to __swi(7) are served by RTX.

No, __swi isn't only available with RTX. The main difference is that RTX reserves a couple of numbers. If I remember correct, __swi(0) to __swi(7) are served by RTX.

Hello,

Use of __swi does not depend on RTX.
The difference is that RTX already contains a SWI handler and SWI functions __swi(0) to __swi(7) are reserved.
If you do not use RTX and want to use SWI functions than you must include an own SWI handler.
Please check example C:\Keil\ARM\Examples\SWI.

Best Regards,
Martin Guenther

You'll find __swi version of USB_WriteEP in Keil USBCDC example, as follows.

C:\Keil\ARM\Boards\Keil\MCB2300\USBCDC

usbhw.h

extern DWORD __swi(8) USB_WriteEP (DWORD EPNum, BYTE *pData, DWORD cnt);

usbhw.c

/*
 *  Write USB Endpoint Data
 *    Parameters:      EPNum: Endpoint Number
 *                       EPNum.0..3: Address
 *                       EPNum.7:    Dir
 *                     pData: Pointer to Data Buffer
 *                     cnt:   Number of bytes to write
 *    Return Value:    Number of bytes written
 */

DWORD __swi(8) USB_WriteEP (DWORD EPNum, BYTE *pData, DWORD cnt);
DWORD __SWI_8              (DWORD EPNum, BYTE *pData, DWORD cnt) {
//DWORD USB_WriteEP (DWORD EPNum, BYTE *pData, DWORD cnt) {
  DWORD n;

  USB_CTRL = ((EPNum & 0x0F) << 2) | CTRL_WR_EN;

  TX_PLENGTH = cnt;

  for (n = 0; n < (cnt + 3) / 4; n++) {
    TX_DATA = *((__packed DWORD *)pData);
    pData += 4;
  }

  USB_CTRL = 0;

  WrCmd(CMD_SEL_EP(EPAdr(EPNum)));
  WrCmd(CMD_VALID_BUF);

  return (cnt);
}

In the background, SWI.s is dragged in from RL_ARM,

;/*****************************************************************************/
;/* SWI.S: SWI Handler                                                        */
;/*****************************************************************************/
;/* This file is part of the uVision/ARM development tools.                   */
;/* Copyright (c) 2005-2006 Keil Software. All rights reserved.               */
;/* This software may only be used under the terms of a valid, current,       */
;/* end user licence from KEIL for a compatible version of KEIL software      */
;/* development tools. Nothing else gives you the right to use this software. */
;/*****************************************************************************/

T_Bit           EQU     0x20

                PRESERVE8                      ; 8-Byte aligned Stack
                AREA    SWI_Area, CODE, READONLY
                ARM

                EXPORT  SWI_Handler
SWI_Handler

                STMFD   SP!, {R12, LR}         ; Store R12, LR
                MRS     R12, SPSR              ; Get SPSR
                STMFD   SP!, {R8, R12}         ; Store R8, SPSR
                TST     R12, #T_Bit            ; Check Thumb Bit
                LDRNEH  R12, [LR,#-2]          ; Thumb: Load Halfword
                BICNE   R12, R12, #0xFF00      ;        Extract SWI Number
                LDREQ   R12, [LR,#-4]          ; ARM:   Load Word
                BICEQ   R12, R12, #0xFF000000  ;        Extract SWI Number

                LDR     R8, SWI_Count
                CMP     R12, R8
                BHS     SWI_Dead               ; Overflow
                ADR     R8, SWI_Table
                LDR     R12, [R8,R12,LSL #2]   ; Load SWI Function Address
                MOV     LR, PC                 ; Return Address
                BX      R12                    ; Call SWI Function

                LDMFD   SP!, {R8, R12}         ; Load R8, SPSR
                MSR     SPSR_cxsf, R12         ; Set SPSR
                LDMFD   SP!, {R12, PC}^        ; Restore R12 and Return

SWI_Dead        B       SWI_Dead               ; None Existing SWI

SWI_Cnt         EQU    (SWI_End-SWI_Table)/4
SWI_Count       DCD     SWI_Cnt

                IMPORT  __SWI_8

SWI_Table
                DCD     SWI_Dead               ; SWI 0 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 1 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 2 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 3 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 4 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 5 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 6 Function Entry used by RTX
                DCD     SWI_Dead               ; SWI 7 Function Entry used by RTX
                DCD     __SWI_8                ; SWI 8 Function Entry
;               ...
SWI_End

                END

Also, LPC2300.s is modified a little to support SWI (SVC)

LPC2300.s

SVC_Stack_Size  EQU     0x00000100



Vectors         LDR     PC, Reset_Addr
                LDR     PC, Undef_Addr
...
...
IRQ_Addr        DCD     IRQ_Handler
FIQ_Addr        DCD     FIQ_Handler

                IMPORT  SWI_Handler

Undef_Handler   B       Undef_Handler
;SWI_Handler     B       SWI_Handler
PAbt_Handler    B       PAbt_Handler
DAbt_Handler    B       DAbt_Handler
IRQ_Handler     B       IRQ_Handler
FIQ_Handler     B       FIQ_Handler

Tsuneo