Lab Exercise: Introduction to the keil mdk-ARM TOOL, C and assembly coding - Processing Text in Assembly Language example

# Overview

In this exercise you will write and compile assembly code and debug the program image on an mbed board (namely the Freedom KL25Z board) using the Keil MDK-ARM tool.

Before you embark on this lab, you need to go through the “Getting Started” document which includes instruction on how you can setup the necessary firmware.

# LAB EXERCISE

## Mixing Assembly Language and C Code

We will use Keil MDK with a C program, but add assembly subroutines to perform string copy and capitalization operations.

Note that some embedded systems are coded purely in assembly language, but most are coded in C with assembly language used only for time-critical processing if at all. This is because the code *development* process is much faster (and hence less expensive) when writing in C when compared to assembly language.

Writing assembly code as functions, which can be called from C code as C functions, result in modular programs, which gives us the best of both worlds: the fast, modular development of C and the high performance of assembly code. It is also possible to add *inline assembly code* to C code, but this requires much greater knowledge of how compilers generate code.

## Main

First we will create the main C function. This function contains two variables (*a* and *b*) with character arrays.

int main(void)

{

const char a[] = "Hello world!";

char b[20];

my\_strcpy(a, b);

my\_capitalize(b);

while (1)

;

}

## Register Use Conventions

There are certain register use conventions which we need to follow if we would like our assembly code to coexist with C code.

### Calling functions and Passing Arguments

When a function calls a subroutine, it places the return address in the link register lr. The arguments (if any) are passed in registers r0 through r3, starting with r0. If there are more than four arguments, or they are too large to fit in 32-bit registers, they are passed on the stack.

### Temporary storage

Registers r0 through r3 can be used for temporary storage if they were not used for arguments, or if the argument value is no longer needed.

### Preserved Registers

Registers r4 through r11 must be preserved by a subroutine. If any must be used, they must be saved first and restored before returning. This is typically done by pushing them to and popping them from the stack.

### Returning from Functions

Because the return address has been stored in the link register, the BX lr instruction will reload the pc with the return address value from the lr. If the function returns a value, it will be passed through register r0.

## String Copy

The function my\_strcpy has two arguments (src, dst). Each is a 32-bit long pointer to a character. In this case, a pointer fits into a register, so argument src is passed through register r0 and dst is passed through r1.

Our function will load a character from memory

\_\_asm void my\_strcpy(const char \*src, char \*dst)

{

loop

LDRB r2, [r0] ; Load byte into r2 from mem. pointed to by r0 (src pointer)

ADDS r0, #1 ; Increment src pointer

STRB r2, [r1] ; Store byte in r2 into memory pointed to by (dst pointer)

ADDS r1, #1 ; Increment dst pointer

CMP r2, #0 ; Was the byte 0?

BNE loop ; If not, repeat the loop

BX lr ; Else return from subroutine

}

## String Capitalization

Let’s look at a subroutine to capitalize all the lower-case letters in the string. We need to load each character, check to see if it is a letter, and if so, capitalize it.

Each character in the string is represented with its ASCII code. For example, ‘A’ is represented with a 65 (0x41), ‘B’ with 66 (0x42), and so on up to ‘Z’ which uses 90 (0x5a). The lower case letters start at ‘a’ (97, or 0x61) and end with ‘z’ (122, or 0x7a). We can convert a lower case letter to an upper case letter by subtracting 32.

\_\_asm void my\_capitalize(char \*str)

{

cap\_loop

LDRB r1, [r0] ; Load byte into r1 from memory pointed to by r0 (str pointer)

CMP r1, #'a'-1 ; compare it with the character before 'a'

BLS cap\_skip ; If byte is lower or same, then skip this byte

CMP r1, #'z' ; Compare it with the 'z' character

BHI cap\_skip ; If it is higher, then skip this byte

SUBS r1,#32 ; Else subtract out difference to capitalize it

STRB r1, [r0] ; Store the capitalized byte back in memory

cap\_skip

ADDS r0, r0, #1 ; Increment str pointer

CMP r1, #0 ; Was the byte 0?

BNE cap\_loop ; If not, repeat the loop

BX lr ; Else return from subroutine


}

The code is shown above. It loads the byte into r1. If the byte is less than ‘a’ then the code skips the rest of the tests and proceeds to finish up the loop iteration.

This code has a quirk – the first compare instruction compares r1 against the character immediately before ‘a’ in the table. Why? What we would like is to compare r1 against ‘a’ and then branch if it is lower. However, there is no branch lower instruction, just branch lower or same (BLS). To use that instruction, we need to reduce by one the value we compare r1 against.

# Lab Procedure

1. Open the asm project.
2. Compile the code.
3. Load it onto your mbed board.
4. Start the Debug Session (Ctrl + F5) and run the program until the opening brace in the main function is highlighted. Open the Registers window (View->Registers Window). What are the values of the stack pointer (r13), link register (r14) and the program counter (r15)? (see picture below).



Address 0x000002BC


Register values

SP = 0x20002FF8, LR = 0x00002C2B, PC = 0x000002BC.

1. Open the Disassembly window (View->Disassembly Window). Which instruction does the yellow arrow point to, and what is its address? How does this address relate to the value of pc? (see picture above)

“SUB sp,sp,#0x28” is at address 0x000002BC,which is the value of PC. This is the next instruction which will be executed.

1. Step one machine instruction using the F10 key while the Disassembly window is selected. Which two registers have changed (they should be highlighted in the Registers window), and how do they relate to the instruction just executed? (see picture below)



Stack pointer

4 bytes long instructions

Program counter

The stack pointer R13 has changed to 0x20002FD0, resulting from subtracting 0x28 from 0x20002FF8. The program counter R15 has changed to 0x000002BE, resulting from executing the add instruction (which is two bytes long).


1. Look at the instructions in the Disassembly window. Do you see any instructions which are four bytes long? If so, what are the first two? (see picture above)

Yes:

BL.W \_Z9my\_strcpyPKcPc and

BL.W \_Z13my\_capitalizePc

1. Continue execution (using F10) until reaching the BL.W \_Z9my\_strcpyPKcPc instruction. What are the values of the SP, PC and LR? (see picture below)



Stack Pointer, Link Register and Program Counter

SP = 0x20002FD0, LR = 0x00002C2B, PC = 0x000002CC.


1. Execute the BL.W instruction. What are the values of the SP, PS and LR? What has changed and why? Does the PC value agree with what is shown in the Disassembly window? (see picture below).

SP = 0x20002FD0, LR = 0x000002D1, PC = 0x00000260. LR has changed because the BL.W instruction saved the return address (old value of PC + length of BL.W instruction +1). PC has changed because the PC is loaded with the address of the subroutine to execute. Yes, the PC matches the disassembly window contents – the yellow arrow points to the instruction at 0x00000260.

1. What registers hold the arguments to my\_strcpy, and what are their contents? (see picture below)

src: register R0, value 0x20002FE8

dst: register R1, value 0x20002FD4




Address of the subroutine

R0: value of scr pointer

R1: value of dst pointer

Stack Pointer, Link Register and Program Counter

1. Watch the “Call Stack + Locals” window, to analyze the variable “a” and “b” (see picture below)



1. What is the value of “a”?


Hello world!

1. What is the value of “b”?

Null characters

1. Single step through the assembly code watching “Call Stack + Locals” window to see the string being copied character by character from a to b. What register holds the character?

R2

1. What are the values of the character, the src pointer, the dst pointer, the link register (R14) and the program counter (R15) when the code reaches the last instruction in the subroutine (BX lr)?


R2 = 0x00000000, src = R0 = 0x20002FF5, dst = R1 = 0x20002FE1, LR = 0x000002D1, PC = 0x0000026C

1. Execute the BX lr instruction. Now what is the value of PC? (see picture below).


PC = 0x000002D0

1. What is the relationship between the PC value and the previous LR value? Explain.

PC is LR-1. The processor resumes executing code at address 0x000002D0, but the last bit of the PC is set to indicate the processor is executing in Thumb mode.



PC

1. Now step through the my\_capitalize subroutine and verify it works correctly, converting b from “Hello world!” to “HELLO WORLD!”.

Characters are capitalized one by one from a to b